# TITLE:  Polynomial Division
# AUTHOR: BazzaB
# EMAIL:  barries_ecdl@hotmail.com
# DATE:   1st December 2003
# MAKE:   Casio
# MODEL:  Updated for CFX-9850G or similar

# NOTES:  In Label A, change the value of 20 to be the highest
# degree of your numerator.
# Ensure you write down the intermediate results as they appear.

# KEYS:
#  ->    assignment            above [ AC/ON ]
#  =>    if-then               shift vars f3 f3
#  [     left bracket          shift [ + ]
#  ]     right bracket         shift [ - ]
#  %     fraction              [ A b/c ] key, above the number 7
#  _     display triangle      shift vars f5
#__________________________________________________

# Needs Subroutine "S-NOTZRO" shown at the end of the main listing.

@@ Program "POLYDIVN"

Lbl A:Norm:0->A~E:20->A:2->B:A->C:Goto H
Lbl B:D->A:A=2->B:B=>Goto E
Lbl C:1->E:1->B:A-1->C:Goto H
Lbl D:D->B
Lbl E:ClrList:Seq(0,X,1,A+1,1->List 1:List 1->List 2
Lbl F:For 1->C To A+1:ClrText:Locate 8,3,"NUMERATOR":Locate 8,4,"COEFF"
Locate 3,4,"X^":Locate 5,4,A-C+1:?->List 1[C
If Not List 1[1:Then Prog "S-NOTZRO":Goto F:IfEnd
Next
Lbl G:For 1->C To B+1:ClrText:Locate 8,3,"DENOMINATOR":Locate 8,4,"COEFF"
Locate 3,4,"X^":Locate 5,4,B-C+1:?->List 2[C
If Not List 2[1:Then Prog "S-NOTZRO":Goto G:IfEnd
Next
For 0->C To A-B:ClrText:Locate 2,4,"- QUOTIENT -"
Locate 1,6,"COEFF OF X^":Locate 12,6,A-B-C:List 1[C+1]%List 2[1->E:E=>E_
For 1->D To B+1:List 1[C+D]-EList 2[D->List 1[C+D
Next:Next
0->B:C+1->C:For C->D To A:List 1[D+1=>1->B:Next
If B:Then For C->D To A:ClrText:Locate 2,4,"- REMAINDER -"
Locate 1,6,"COEFF OF X^":Locate 12,6,A-D:List 1[D+1->E:E=>E_
Next
IfEnd:ClrText:"END"_
Goto A
Lbl H:Do:ClrText
Locate 3,4,"FROM":Locate 8,4,C:Locate 5,5,"TO":Locate 8,5,B
Not E=>"NUMERATOR DEGREE "?->D:E=>"DENOMINATOR DEGREE "?->D
LpWhile Frac D+(D<B)+(D>C:E=>Goto D:Goto B
#__________________________________________________

@@ Program "S-NOTZRO"

Clrtext:Locate 7,4,"THAT VALUE":Locate 7,5,"CAN NOT BE":Locate 10,6,"ZERO"
For 1->J To 3:For 1->K To 200:Next:Locate 11,5,"..."
For 1->K To 99:Next:Locate 11,5,"NOT"
Next:For 1->K To 400:Next
#__________________________________________________