# TITLE:  Date of Easter Sunday for Years 1753 to 4099
# AUTHOR: BazzaB
# EMAIL:  barries_ecdl@hotmail.com
# DATE:   1st November 2003
# MAKE:   Casio
# MODEL:  CFX-9850G or similar

# NOTES: Follow the on-screen prompts.
#
#        Line 6 of the program listing is a single space in quotes.

# KEYS:
#   ->     assignment     above [ AC/ON]
#   =>     if-then        shift vars f3 f3
#   \^-1   reciprocal     shift [ ) ] key
#___________________________________________________________


@@ Program "EASTERSN"

Lbl 1
Norm
0->A~F
ClrText
"EASTER SUNDAY"
" "         
"ENTER YEAR"
"FROM 1753 TO 4099"
?->Y
Frac Y+(Y<1753)+(Y>4099=>Goto 1
Y-19Int 19\^-1Y->A
Int .01Y->B
Int .25B->C
Y-100B->D
2B-8C->E
Int (25\^-1B+.32->F
Int (3\^-1(B-F+1->F
19A+B-C-F+15->B
B-30Int 30\^-1B->B
2Int .25D->C
D-2C->D
32+C+E->C
C-B-D->C
C-7Int 7\^-1C->C
Int (451\^-1(A+11B+22C->A
B+C-7A+114->A
Int 31\^-1A->B
A+1-31B->A
ClrText
"EASTER SUNDAY"
Locate 1,3,"FOR"
Locate 5,3,Y
Locate 1,4,"IS MARCH"
B=4=>Locate 4,4,"APRIL"
Locate 10,4,A
12-(A<10->B
Locate B,4,"TH"
(A=1)+(A=21)+(A=31=>Locate B,4,"ST"
(A=2)+(A=22=>Locate B,4,"ND"
(A=3)+(A=23=>Locate B,4,"RD"